Right Click to make a Text File in Finder on Mac

I think I might have found the best way to create text files in Finder. And not by right-clicking to a context menu. Instead I set up a shortcut with some custom code. I made this work using an Automator script (code below), and then making a keyboard shortcut in System Preferences (instructions below).

The Problem:

Do you ever want to make a document instantly in the Finder? We can already do a similar action for “New Folder”, which works great. But what if you want to make a styles.css or a tps-report.docx? Why can’t we make a “New File” with ease?

The Solution:

I couldn’t figure out a way to make it exactly like this. But I this process led me to something even better: a keyboard shortcut that creates a text file in your current Finder window, and then opens it right up.

Here it is in action:

Its a fast way to make new files.

• You can press it in any finder window
• it pops up a dialog box asking to name the file,
• it saves it in your folder, and
• it automatically opens the file in my text editor.
• (and if no default editor is set, it defaults to TextEdit)

I’ve outlined the steps with video and text instructions below. It’ll take you a couple minutes:

First, create the Quick Action in Automator

1. Open up “Automator” (you can search for it using Spotlight)
2. Choose “New Document” and select “Quick Action.”
3. Type “Apple into the search and select “Run AppleScript”
4. At the top, set “Workflow receives” to “no input” and “Finder.app”
5. Replace the placeholder script with the AppleScript below
6. Save it and call it New File… (I did mine with the dot dot dot)

on run {input, parameters}
    tell application "Finder"
        if (count of windows) is not 0 then
            set currentFolder to (target of front window) as alias
        else
            set currentFolder to (desktop as alias)
        end if
    end tell
    set folderPath to POSIX path of currentFolder
    if folderPath does not end with "/" then
        set folderPath to folderPath & "/"
    end if
    set fileName to text returned of (display dialog "Enter file name:" default answer "untitled.txt")
    set filePath to folderPath & fileName
    do shell script "touch " & quoted form of filePath
    try
        if fileName starts with "." then
            do shell script "open -a TextEdit " & quoted form of filePath
        else
            do shell script "open " & quoted form of filePath
        end if
    on error errMsg
        display notification "Could not open file automatically: " & errMsg
    end try
    return input
end run

Halfway there, next make your shortcut

The key here is to make sure that your “Menu Title” is the same name as the what you saved your Quick Action in the steps above:

1. Go to System Settings → Keyboard → Keyboard Shortcuts
2. Select “App Shortcuts” on the left column
3. Select “Finder” for the Application
4. Type in “New File…” (with the dots) for the Menu Title
5. Press your shortcut below for the Keyboard Shortcut

That’s it, your done!

Now when I’m in Finder, I hit ⌃ ⌥ ⌘ + N and a new file is created instantly, right where I need it, AND it opens up in my code editor. I went with this chunky keyboard shortcut (because its the best), but you can set it as whatever you want.

Why this is better than right-click > new file

• Its faster. Right-clicking to create a file in finder is intuitive, but this is absolutely faster.
• It opens the file right up, as soon as you name it. This is great if you’re just making files and pasting them in like a vibe coder.
• It handles hidden dot files like .env.local or .gitignore without choking. If the file type doesn’t have a default app, it’ll still open it in TextEdit so you can get started editing.
• It doesn’t rely on third-party apps or hacks. It’s just a little AppleScript wrapped in Automator.

It also matches how I think when I’m working — “I need a file here, right now”—instead of jumping between apps or dragging things around.

I’ve been working on documenting all my custom workflows and quick actions. I worry that someday I’ll need start over on a fresh install of Mac OS and have to cobble everything back together. Hope that never happens, but if it does, maybe I’ll have this to fall back on.

Is there a better way? Maybe? Let me know below!